c++ runtime - global object ctor (2) - 透過 elf section 來呼叫 global ctor

如果你有看之前的 c++ runtime - global object ctor (0), (1) 應該知道 g++ 會為 global object constructor 準備一個 _GLOBALxxx 的 function。只要 call 它, 就會完成所有 global object ctor 的呼叫。

g++ 4.4, g++ 4.6 將 _GLOBAL__sub_I_ab 放在 .ctor section
g++ 4.7 將 _GLOBAL__sub_I_ab 放在 .init_array section

g++ 4.6

[ 2] .ctors PROGBITS 000008ac 0008ac 000004 00 WA 0 0 4

g++ 4.7.1

[ 2] .init_array INIT_ARRAY 00000938 000938 000004 00 WA 0 0 4

運用類似 init bss 的技巧, 我們在 linker script (cpp.ld) 插入 symbol, L12 ~ L24, 只要其中一段就可以, 不過我為了支援 g++ 4.4, g++4.6, g++ 4.7 所以補了兩段。

但是我不知道 g++ 4.7.1 的 _GLOBAL__sub_I_ab 放在那個 section, 無法使用 L21 的指令, 只好用 L13 ~ L17 這樣有點遜的方法來處理。

cpp.ld

 /* for cb.c */
 ENTRY(_start);
 SECTIONS
 {
 
     . = 0x100;
     .text :
     {
         *(.text)
         *(.gnu.linkonce.t*)
     }
     /* for g++ 4.7 */
     .init_array :
     {
       __start_global_ctor__ = .;
     }
     __end_global_ctor__ = .;
     .ctors :
     {
       start_ctors = .; _start_ctors = .; __start_ctors = .;
       *(.ctor*)
       end_ctors = .; _end_ctors = .; __end_ctors = .;
      }
      /*
     .dtors :
     {
       start_dtors = .; _start_dtors = .; __start_dtors = .;
       *(.dtor*)
       end_dtors = .; _end_dtors = .; __end_dtors = .;
       . = ALIGN(0x1000);
      }
      */
 
     .rodata :
     {
         *(.rodata*)
         *(.gnu.linkonce.r*)
     }
 
     .data :
     {
         *(.data)
         *(.gnu.linkonce.d*)
     }
 
     .bss :
     {
         sbss = .; __bss_start__ = .;
         *(COMMON)
         *(.bss)
         *(.gnu.linkonce.b*)
         ebss = .; __bss_end__ = .;
     }
 
     /DISCARD/ :
     {
         *(.comment)
         *(.eh_frame) /* discard this, unless you are implementing 

                             runtime support for C++ exceptions. */
     }
 }

 # call global object ctor
 init_cpp_global_asm:
 #if __GNUC__ >= 4 && __GNUC_MINOR__ >= 7
   mov $__end_global_ctor__, %edi    /* Destination */
   mov $__start_global_ctor__, %esi   /* Source */
 #else
   mov $__end_ctors, %edi    /* Destination */
   mov $__start_ctors, %esi   /* Source */
 #endif
   jmp 2f
 1:
   mov %esi, %ebx 
   calll *(%ebx)
   add $4, %esi
 2:
   cmp %edi, %esi
   jne 1b
   ret

init_cpp_global_asm 依序呼叫 linker script symbol __end_global_ctor__, __start_global_ctor__ 之間的位址, 不過在這例子中:

00000944 A __end_global_ctor__
00000940 T __start_global_ctor__

所以只有一個 4byte 位址, 4e 04 00 00 => 0x0000044e (_GLOBAL__sub_I_ab),
如果你忘記這怎麼來的請參考:  c++ runtime - global object ctor (0)
 

   calll *(%ebx)

呼叫它就對了。at &t call 指令語法很奇怪, 別擔心, 常看就會習慣了。

寫成下面的程式碼也可以:

   mov $__start_global_ctor__, %ebx 
   calll *(%ebx)

這樣應該比較好懂, 沒有惱人的 loop, 不過你得知道這樣會有什麼風險, 能看懂這篇的朋友我相信應該有能力處理這小問題。也應該換你們踩踩地雷, 保證印象深刻。

   calll init_cpp_global_asm
   calll cpp_main

最後在 c++ main 之前呼叫 init_cpp_global_asm (cpp_main) 就完成 global object constructor 的呼叫。global object constructor 的秘密到此結束, 再來我會談談 global object destructor。
 

cpp_init.S

 # init c++ runtime
 
 #define DOS
 
 # How to make G++ preprocessor output a newline in a macro?
 # ref: http://stackoverflow.com/questions/2271078/how-to-make-g-preprocessor-output-a-newline-in-a-macro
 #define PRINT_REG(REG)  /*
 */  pushl $REG /*
 */  calll _Z9print_strPKc /*
 */  addl $4, %esp /*
 */  pushl $16 /*
 */  pushl %REG /*
 */  calll _Z13s16_print_intii /*
 */  addl $8, %esp /*
 */  pushl $CRLF /*
 */  calll _Z9print_strPKc /*
 */  addl $4, %esp
 
 #define PRINT_VAR(VAR)  /*
 */  pushl $var /*
 */  calll _Z9print_strPKc /*
 */  addl $4, %esp /*
 */  pushl $16 /*
 */  pushl VAR /*
 */  calll _Z13s16_print_intii /*
 */  addl $8, %esp /*
 */  pushl $CRLF /*
 */  calll _Z9print_strPKc /*
 */  addl $4, %esp
 .code16
 .extern __bss_start__
 .extern __bss_end__
 .extern __start_ctors
 .extern __end_ctors
 .extern cpp_main
 .extern obj_count
 
 
 .text
   jmp _start
 .global _start
 _start:
   xchg %bx, %bx
 #if 1
   mov %cs, %ax
   mov %ax, %ds
   mov %ax, %ss
 
 #endif

 
   call init_bss_asm # in dos need not init bss by myself
 
 
   mov obj_count, %bx
   calll disp_bx
 
   # call _GLOBAL__I_XX invoke global object ctor, 
   # in dos environment use 16 or 32 bit address? look like 32 bit
   calll init_cpp_global_asm
   calll cpp_main
 84   calll g_dtors

   mov     $0x4c00, %ax
   int     $0x21   # 回到 DOS
 

 
 # call global object ctor
 init_cpp_global_asm:
 #if __GNUC__ >= 4 && __GNUC_MINOR__ >= 7
   mov $__end_global_ctor__, %edi    /* Destination */
   mov $__start_global_ctor__, %esi   /* Source */
 #else
   mov $__end_ctors, %edi    /* Destination */
   mov $__start_ctors, %esi   /* Source */
 #endif
   jmp 2f
 1:
   mov %esi, %ebx 
   calll *(%ebx)
   add $4, %esi
 2:
   cmp %edi, %esi
   jne 1b
   ret
 
 # init bss
 init_bss_asm:
   movw $__bss_end__, %di    /* Destination */
   movw $__bss_start__, %si   /* Source */
   movw %ds, %bx
   movw %bx, %es
   jmp 2f
 1:
   mov $0, %eax
   movw %si, %ax
   movb $0x0, %es:(%eax)
   add $1, %si
 

 
   
 2:
   cmpw %di, %si
   jne 1b
 
   ret
 

 
 disp_al:
         pushl   %ebx
         pushl   %ecx
         pushl   %edx
 
         movl (cur_pos), %ebx
         movb    $0x0c, %ah # 0000: 黑底    1100: 紅字
         movb    %al, %dl
         shr     $4, %al
         movl    $2, %ecx
 .begin_1:
         andb    $0x0f, %al
         cmp     $9, %al
         ja      .31          # cf=0, zf=0, above 9 (>9)
         #addb   $'0', %al
         addb    $0x30, %al
         jmp     .41
 .31:
         sub     $0x0A, %al
         #add    $'A', %al
         add     $0x41, %al
 .41:

         movw    %ax, %gs:(%ebx)

         add     $2, %ebx
 
         mov %ebx, cur_pos
 
         mov     %dl, %al
         loop    .begin_1
         addl    $2, %ebx
 
         popl    %edx
         popl    %ecx
         popl    %ebx
 
         ret
 
 disp_bx:
   pushl %eax
   mov %bx, %ax
   shr $8, %ax
   call disp_al
   mov %bl, %al
   call disp_al
   popl %eax
   ret
 
 .data
 CRLF: .asciz "\r\n"
 cs: .asciz "%CS: "
 ds: .asciz "%DS: "
 ss: .asciz "%SS: "
 var: .asciz "var: "
 cur_pos: .int 0