巨大的一小步 - 從真實模式進入保護模式

參考了這兩本,自己動手寫作業系統 <于淵>、自己動手寫作業系統 <楊文博>, 終於將 gas AT & T 的版本改出來。

 /* chapter3/1/loader.S

    Author: Wenbo Yang <solrex@gmail.com> <http://solrex.cn>

    This file is part of the source code of book "Write Your Own OS with Free
    and Open Source Software". Homepage @ <http://share.solrex.cn/WriteOS/>.

    This file is licensed under the GNU General Public License; either
    version 3 of the License, or (at your option) any later version. */

 #include "pm.h"

 .code16
 .text
     jmp LABEL_BEGIN     /* jump over the .data section. */

 /* NOTE! Wenbo-20080512: Actually here we put the normal .data section into
    the .code section. For application SW, it is not allowed. However, we are
    writing an OS. That is OK. Because there is no OS to complain about
    that behavior. :) */

 /* Global Descriptor Table */
 LABEL_GDT:          Descriptor  0,                        0, 0
 LABEL_DESC_NORMAL:  Descriptor  0,         0xffff, DA_DRW    # Normal descriptor is for back to real mode.
 LABEL_DESC_CODE32:  Descriptor  0,       (SegCode32Len - 1), (DA_C + DA_32)
 LABEL_DESC_CODE16:  Descriptor    0,         0xffff, DA_C      # 非一致程式碼段, 16
 LABEL_DESC_VIDEO:   Descriptor  0xB8000,             0xffff, DA_DRW

 .set GdtLen, (. - LABEL_GDT)  /* GDT Length */

 GdtPtr: .2byte  (GdtLen - 1)  /* GDT Limit */
         .4byte  0             /* GDT Base */

 /* GDT Selector */
 .set SelectorNormal, (LABEL_DESC_NORMAL - LABEL_GDT)
 .set    SelectorCode32, (LABEL_DESC_CODE32 - LABEL_GDT)
 .set SelectorCode16, (LABEL_DESC_CODE16 - LABEL_GDT)
 .set    SelectorVideo,  (LABEL_DESC_VIDEO  - LABEL_GDT)

 /* Program starts here. */
 LABEL_BEGIN:
     mov     %cs, %ax    /* Move code segment address(CS) to data segment */
     mov     %ax, %ds    /* register(DS), ES and SS. Because we have      */
     mov     %ax, %es    /* embedded .data section into .code section in  */
     mov     %ax, %ss    /* the start(mentioned in the NOTE above).       */

     movw     $0x100, %sp
     nop
     movw %ax, (LABEL_GO_BACK_TO_REAL+3) # modify segment value, indexed memory mode, ref  professional aeesmbly language p 102.

     /* Initialize 16-bits code segment descriptor. */
     xor     %eax, %eax
     mov     %cs, %ax
     shl     $4, %eax
     addl    $(LABEL_SEG_CODE16), %eax
     movw    %ax, (LABEL_DESC_CODE16 + 2)
     shr     $16, %eax
     movb    %al, (LABEL_DESC_CODE16 + 4)
     movb    %ah, (LABEL_DESC_CODE16 + 7)

     /* Initialize 32-bits code segment descriptor. */
     xor     %eax, %eax
     mov     %cs, %ax
     shl     $4, %eax
     addl    $(LABEL_SEG_CODE32), %eax
     movw    %ax, (LABEL_DESC_CODE32 + 2)
     shr     $16, %eax
     movb    %al, (LABEL_DESC_CODE32 + 4)
     movb    %ah, (LABEL_DESC_CODE32 + 7)

     /* Prepared for loading GDTR */
     xor     %eax, %eax
     mov     %ds, %ax
     shl     $4, %eax
     add     $(LABEL_GDT), %eax      /* eax <- gdt base*/
     movl    %eax, (GdtPtr + 2)

     /* Load GDTR(Global Descriptor Table Register) */
     lgdtw   GdtPtr

     /* Clear Interrupt Flags */
     cli

     /* Open A20 line. */
     inb     $0x92, %al
     orb     $0b00000010, %al
     outb    %al, $0x92

     /* Enable protect mode, PE bit of CR0. */
     movl    %cr0, %eax
     orl     $1, %eax
     movl    %eax, %cr0

     /* Mixed-Size Jump. */
     ljmp $SelectorCode32, $0       /* Thanks to earthengine@gmail, I got */
                                     /* this mixed-size jump insn of gas.  */
                                     /* this calls far jump (ptr 16:32) in intel manual) */

 LABEL_REAL_ENTRY:               # 從保護模式跳回到實模式就到了這裡
         mov     %cx, %ax
         mov     %ax, %ds
         mov     %ax, %es
         mov     %ax, %ss

 #        mov     sp, [SPValueInRealMode]

         in      $0x92, %al
         and     $0b11111101, %al   #  close A20 line
         out     %al, $0x92

         sti                     # 開中斷

         mov     $0x4c00, %ax
         int     $0x21             #  回到 DOS
 # END of .code16

 LABEL_SEG_CODE32:
 .code32
     mov     $(SelectorVideo), %ax
     mov     %ax, %gs                /* Video segment selector(dest) */

     movl    $((80 * 10 + 0) * 2), %edi
     movb    $0xC, %ah               /* 0000: Black Back 1100: Red Front */
     movb    $'P', %al

     mov     %ax, %gs:(%edi)

     /* Stop here, infinite loop. */
 #    jmp     .
     ljmpl     $SelectorCode16,$0

 /* Get the length of 32-bit segment code. */
 .set    SegCode32Len, . - LABEL_SEG_CODE32

 LABEL_SEG_CODE16:
 .code16
     #jmp     .
         # back to real mode
         mov     $SelectorNormal, %ax
         mov     %ax, %ds
         mov     %ax, %es
         mov     %ax, %fs
         mov     %ax, %gs
         mov     %ax, %ss

         mov     %cr0, %eax
         and     $0b11111110, %al
         mov     %eax, %cr0


 LABEL_GO_BACK_TO_REAL:
 #.2byte 0xea66
 #.4byte 0x00000000
 #.2byte LABEL_REAL_ENTRY
     jmp     $0, $LABEL_REAL_ENTRY      # 段位址會在程序開始處被設置成正確的值


 .set Code16Len, . - LABEL_SEG_CODE16

↓ 進入保護模式, 印出紅色 P, 再切回真實模式並回到 DOS。

From write_os

 /*
    ref: Orange'S：一个操作系统的实现
    do the 5M memory r/w
  */
 /* chapter3/1/loader.S

    Author: Wenbo Yang <solrex@gmail.com> <http://solrex.cn>

    This file is part of the source code of book "Write Your Own OS with Free
    and Open Source Software". Homepage @ <http://share.solrex.cn/WriteOS/>.

    This file is licensed under the GNU General Public License; either
    version 3 of the License, or (at your option) any later version. */

 #include "pm.h"

 .code16
 .text
     jmp LABEL_BEGIN     /* jump over the .data section. */

 /* NOTE! Wenbo-20080512: Actually here we put the normal .data section into
    the .code section. For application SW, it is not allowed. However, we are
    writing an OS. That is OK. Because there is no OS to complain about
    that behavior. :) */

 /* Global Descriptor Table */
 LABEL_GDT:          Descriptor  0,                        0, 0
 LABEL_DESC_NORMAL:  Descriptor  0,         0xffff, DA_DRW    # Normal descriptor is for back to real mode.
 LABEL_DESC_CODE32:  Descriptor  0,       (SegCode32Len - 1), (DA_C + DA_32)
 LABEL_DESC_CODE16:  Descriptor    0,         0xffff, DA_C      # 非一致程式碼段, 16
 LABEL_DESC_DATA:   Descriptor    0,      DataLen-1, DA_DRW    # Data
 LABEL_DESC_STACK:  Descriptor    0,     TopOfStack, DA_DRWA+DA_32 # Stack, 32 位
 LABEL_DESC_TEST: Descriptor 0x500000, 0xffff, DA_DRW
 LABEL_DESC_VIDEO:   Descriptor  0xB8000, 0xffff, DA_DRW

 .set GdtLen, (. - LABEL_GDT)  /* GDT Length */

 GdtPtr: .2byte  (GdtLen - 1)  /* GDT Limit */
         .4byte  0             /* GDT Base */

 /* GDT Selector */
 .set SelectorNormal, (LABEL_DESC_NORMAL - LABEL_GDT)
 .set    SelectorCode32, (LABEL_DESC_CODE32 - LABEL_GDT)
 .set SelectorCode16, (LABEL_DESC_CODE16 - LABEL_GDT)
 .set SelectorData, (LABEL_DESC_DATA         - LABEL_GDT)
 .set SelectorStack, (LABEL_DESC_STACK        - LABEL_GDT)
 .set SelectorTest, (LABEL_DESC_TEST         - LABEL_GDT)
 .set    SelectorVideo,  (LABEL_DESC_VIDEO  - LABEL_GDT)


 /* Program starts here. */
 LABEL_BEGIN:
     mov     %cs, %ax    /* Move code segment address(CS) to data segment */
     mov     %ax, %ds    /* register(DS), ES and SS. Because we have      */
     mov     %ax, %es    /* embedded .data section into .code section in  */
     mov     %ax, %ss    /* the start(mentioned in the NOTE above).       */

     movw     $0x100, %sp
     nop
     movw %ax, (LABEL_GO_BACK_TO_REAL+3) # modify segment value, indexed memory mode, ref  professional aeesmbly language p 102.

     /* Initialize 16-bits code segment descriptor. */
     xor     %eax, %eax
     mov     %cs, %ax
     shl     $4, %eax
     addl    $(LABEL_SEG_CODE16), %eax
     movw    %ax, (LABEL_DESC_CODE16 + 2)
     shr     $16, %eax
     movb    %al, (LABEL_DESC_CODE16 + 4)
     movb    %ah, (LABEL_DESC_CODE16 + 7)

     /* Initialize 32-bits code segment descriptor. */
     xor     %eax, %eax
     mov     %cs, %ax
     shl     $4, %eax
     addl    $(LABEL_SEG_CODE32), %eax
     movw    %ax, (LABEL_DESC_CODE32 + 2)
     shr     $16, %eax
     movb    %al, (LABEL_DESC_CODE32 + 4)
     movb    %ah, (LABEL_DESC_CODE32 + 7)

  # initialize data segment descriptor
  xor %eax, %eax
  mov %ds, %ax
  shl $4, %eax
  addl $(LABEL_DATA), %eax
  movw %ax, (LABEL_DESC_DATA + 2)
  shr $16, %eax
  movb %al, (LABEL_DESC_DATA + 4)
  movb %ah, (LABEL_DESC_DATA + 7)

  # initialize stack segment descriptor
  xor %eax, %eax
  mov %ds, %ax
  shl $4, %eax
  addl $(LABEL_STACK), %eax
  movw %ax, (LABEL_DESC_STACK + 2)
  shr $16, %eax
  movb %al, (LABEL_DESC_STACK + 4)
  movb %ah, (LABEL_DESC_STACK + 7)

     /* Prepared for loading GDTR */
     xor     %eax, %eax
     mov     %ds, %ax
     shl     $4, %eax
     add     $(LABEL_GDT), %eax      /* eax <- gdt base*/
     movl    %eax, (GdtPtr + 2)

     /* Load GDTR(Global Descriptor Table Register) */
     lgdtw   GdtPtr

     /* Clear Interrupt Flags */
     cli

     /* Open A20 line. */
     inb     $0x92, %al
     orb     $0b00000010, %al
     outb    %al, $0x92

     /* Enable protect mode, PE bit of CR0. */
     movl    %cr0, %eax
     orl     $1, %eax
     movl    %eax, %cr0

     /* Mixed-Size Jump. */
     ljmp $SelectorCode32, $0       /* Thanks to earthengine@gmail, I got */
                                     /* this mixed-size jump insn of gas.  */
                                     /* this calls far jump (ptr 16:32) in intel manual) */

 LABEL_REAL_ENTRY:               # 從保護模式跳回到實模式就到了這裡
         mov     %cx, %ax
         mov     %ax, %ds
         mov     %ax, %es
         mov     %ax, %ss

 #        mov     sp, [SPValueInRealMode]

         in      $0x92, %al
         and     $0b11111101, %al   #  close A20 line
         out     %al, $0x92

         sti                     # 開中斷

         mov     $0x4c00, %ax
         int     $0x21             #  回到 DOS
 # END of .code16

 LABEL_SEG_CODE32:
 .code32

  mov $(SelectorData), %ax
  mov %ax, %ds   # 資料段選擇子
  mov $(SelectorTest), %ax
  mov %ax, %es   # 測試段選擇子




     mov     $(SelectorVideo), %ax
     mov     %ax, %gs                /* Video segment selector(dest) */

  mov $(SelectorStack), %ax
  mov %ax, %ss   # 堆疊段選擇子

  mov $(TopOfStack), %esp

 /*
     movl    $((80 * 10 + 0) * 2), %edi
     movb    $0xC, %ah               # 0000: Black Back 1100: Red Front
     movb    $'P', %al

     mov     %ax, %gs:(%edi)
 */

  # print string "In Protect Mode now. ^-^"
  movb $0x0c, %ah # 0000: 黑底    1100: 紅字
  xor %esi, %esi
  xor %edi, %edi
  mov $(OffsetPMMessage), %esi # data string offset
  movl $((80 * 10 + 0) * 2), %edi # 目的資料偏移。螢幕第 10 行, 第 0 列。
  cld # Clear Direction Flag, ref: http://www.fermi.mn.it/linux/quarta/x86/cld.htm
             # After CLD is executed, string operations will increment the index
             # (SI and/or DI) that they use.
 .1:
  lodsb # For legacy mode, Load byte at address DS:(E)SI into AL.
               # For 64-bit mode load byte at address (R)SI into AL.
               # ref: http://siyobik.info/main/reference/instruction/LODS%2FLODSB%2FLODSW%2FLODSD%2FLODSQ
  test %al, %al # result is 0, zf sets to 1.
  jz .2 # zf = 1 jump
 # mov [gs:edi], ax
         mov     %ax, %gs:(%edi)
  add $2, %edi
  jmp .1
 .2: # 顯示完畢

 #push  %eax                       # Multiboot magic number
 #   push  %ebx                       # Multiboot data structure

 # call kmain
  call DispReturn
         #movb $0xa9, %al
  #call DispAL

  call TestRead
  call TestWrite
  call TestRead


     ljmpl     $SelectorCode16,$0
     # jmpl     $SelectorCode16,$0 # it works

 # ------------------------------------------------------------------------
 TestRead:
  xor %esi, %esi
  mov $8, %ecx
 .loop:
  mov %es:(%esi), %al
  call DispAL
  inc %esi
  loop .loop
  call DispReturn

  ret
 # TestRead 結束-----------------------------------------------------------


 # ------------------------------------------------------------------------
 TestWrite:
  pushl %esi
  pushl %edi
  xor %esi, %esi
  xor %edi, %edi
  mov $(OffsetStrTest), %esi # data offset
  cld # Clear Direction Flag, ref: http://www.fermi.mn.it/linux/quarta/x86/cld.htm
             # After CLD is executed, string operations will increment the index
             # (SI and/or DI) that they use.
 .6:
  lodsb # For legacy mode, Load byte at address DS:(E)SI into AL.
               # For 64-bit mode load byte at address (R)SI into AL.
               # ref: http://siyobik.info/main/reference/instruction/LODS%2FLODSB%2FLODSW%2FLODSD%2FLODSQ

  test %al, %al
  jz .5 # zf = 1 jump
 # mov [es:edi], al
  mov %al, %es:(%edi)
  inc %edi
  jmp .6
 .5:

  popl %edi
  popl %esi
  ret
 # TestWrite 結束----------------------------------------------------------


 # ------------------------------------------------------------------------
 # 顯示 AL 中的數字
 # 默認地:
 # 數字已經存在 AL 中
 # edi 始終指向要顯示的下一個字元的位置
 # 被改變的暫存器:
 # ax, edi
 # ------------------------------------------------------------------------
 DispAL:
  pushl %ecx
  pushl %edx

  movb $0x0c, %ah # 0000: 黑底    1100: 紅字
  movb %al, %dl
  shr $4, %al
  movl $2, %ecx
 .begin:
  andb $0x0f, %al
  cmp $9, %al
  ja .3          # cf=0, zf=0, above 9 (>9)
  #addb $'0', %al
  addb $0x30, %al
  jmp .4
 .3:
  sub $0x0A, %al
  #add $'A', %al
  add $0x41, %al
 .4:
  #mov [gs:edi], ax
  mov %ax, %gs:(%edi)
  add $2, %edi

  mov %dl, %al
  loop .begin
  add $2, %edi

  popl %edx
  popl %ecx

  ret
 # DispAL 結束-------------------------------------------------------------


 # ------------------------------------------------------------------------
 DispReturn:
  pushl %eax
  pushl %ebx
  mov %edi, %eax
  movb $160, %bl
  divb %bl          # %eax/160, 商 al, 餘數 ah.
  and $0x0FF, %eax
  inc %eax         # ++ %eax
  mov $160, %bl
  mul %bl
  mov %eax, %edi
  popl %ebx
  popl %eax
  ret
 # DispReturn 結束---------------------------------------------------------

 /*
 kmain:
         pushl   %ebp
         movl    %esp, %ebp
         popl    %ebp
         ret
         .size   kmain, .-kmain
         .ident  "GCC: (Ubuntu/Linaro 4.5.2-8ubuntu4) 4.5.2"
 */
 #        .section        .note.GNU-stack,"",@progbits


 /* Get the length of 32-bit segment code. */
 .set    SegCode32Len, . - LABEL_SEG_CODE32

 #[SECTION .data1]         ; 資料段
 #ALIGN   32
 #[BITS   32]
 LABEL_DATA:
 SPValueInRealMode: .2byte 0x0
 # string
 PMMessage:              .ascii      "In Protect Mode now. ^-^\0"   # 在保護模式中顯示
 .set    OffsetPMMessage, (PMMessage - LABEL_DATA)
 #StrTest:                .ascii "B\0"
 StrTest:                .ascii "ABCDEFGHIJKLMNOPQRSTUVWXYZ\0"
 #OffsetStrTest           equ     StrTest - $$
 .set OffsetStrTest , (StrTest - LABEL_DATA)
 #DataLen                 equ     $ - LABEL_DATA
 .set DataLen, .  - LABEL_DATA
 /* 32-bit global stack segment. */
 LABEL_STACK:
 .space  512, 0
 .set    TopOfStack, (. - LABEL_STACK - 1)

 # END of [SECTION .data1]


 LABEL_SEG_CODE16:
 .code16
     #jmp     .
         # back to real mode
         mov     $SelectorNormal, %ax
         mov     %ax, %ds
         mov     %ax, %es
         mov     %ax, %fs
         mov     %ax, %gs
         mov     %ax, %ss

         mov     %cr0, %eax
         and     $0b11111110, %al
         mov     %eax, %cr0


 LABEL_GO_BACK_TO_REAL:
 #.2byte 0xea66
 #.4byte 0x00000000
 #.2byte LABEL_REAL_ENTRY
     jmp     $0, $LABEL_REAL_ENTRY      # 段位址會在程序開始處被設置成正確的值


 .set Code16Len, . - LABEL_SEG_CODE16

↓ read/write 5M 的位址。


這個程式可以在 freedos 上執行, 會進入保護模式並印出一個字元 P, 再切回真實模式並回到 freedos 提示符號。

下面是 linker script:

solrex_x86_dos.ld

 /* chapter3/1/solrex_x86_dos.ld
 
    Author: Wenbo Yang <solrex@gmail.com> <http://solrex.cn>
 
    This file is part of the source code of book "Write Your Own OS with Free
    and Open Source Software". Homepage @ <http://share.solrex.cn/WriteOS/>.
 
    This file is licensed under the GNU General Public License; either
    version 3 of the License, or (at your option) any later version. */
 
 SECTIONS
 {
   . = 0x0100;
   .text :
   {
     _ftext = .;
   } = 0
 }

使用以下指令編譯並聯結：

gcc -c loader_back_to_dos.S
ld loader_back_to_dos.o -o loader_back_to_dos.elf -Tsolrex_x86_dos.ld
objcopy -R .pdr -R .comment -R.note -S -O binary loader_back_to_dos.elf loader_back_to_dos.com

測試:
到 http://bochs.sourceforge.net/diskimages.html 下載 freedos image, untar 之後, 使用 qemu 即可測試。

qemu -fda freedos-img/a.img -fdb pm.img

pm.img 是自己動手寫作業系統 <于淵>裡頭提供的軟碟 image, 透過

sudo mount -o loop pm.img /mnt/floppy/
sudo cp loader_back_to_dos.com  /mnt/floppy/t.com
sudo umount /mnt/floppy

將 loader_back_to_dos.com copy 到此軟碟 image (t.com)。

沒錯誤的話, 就會看到紅色的 P 字元, 並回到 dos prompt。
a: 是 a.img (freedos), b: 就會看到這軟碟 image 的程式。

印出一個 P 字元沒想到是這麼累的事情, 我希望學習 GAS AT&T 語法, 所以才會這麼辛苦, 若不堅持, 其實看自己動手寫作業系統 <于淵>就可以了。

程式碼沒解釋是吧！那怎麼看得懂, 當然看不懂, 不過這部份請自己看自己動手寫作業系統 <于淵>, 書上寫的很清楚, 但是我的組合語言功力不夠, 短短 92 行程式, 花了我半天時間才看懂, 不過保護模式的硬體架構需要先了解。不想花錢就看自己動手寫作業系統 <楊文博>這本, 接下來的路雖然還很長, 不過應該好走多了。

20110916 補充:

編成 .com 檔案果然有好處, 後來發現 dosbox 也可以順利執行, 比起這些有的沒的步驟簡單多了。

dosbox

in dosbox

mount d: /test/code
d:
a.com

/test/code 是 linux 下的目錄, mount 成 d 槽, 這樣就搞定了。
ctrl+f5 抓圖, 圖儲存在 /home_dir/.dosbox/capture。

這個程式耗費我不少腦力, 組合語言不熟看 code 就是很痛苦, 除了查 x86 組合語言指令, 還搭配組合語言書籍, 光是 DispReturn, DispAL, TestRead, TestWrite 這幾個 function call 就耗掉不少腦力, 還要轉換 nasm syntax to at&t syntax, 真是累人。

不過這些努力是有回報的, 我開始慢慢上軌道了。

dosbox 環境有些問題, 錯誤的程式碼還是可以正常執行, 目前不使用 dosbox 來做測試。